[ObjC ARC] Converts ios/chrome/browser/ui/infobars:infobars to ARC.

ios/chrome/browser/ui/infobars/infobar_view.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/infobars/infobar_view.h"
 
 #import <CoreGraphics/CoreGraphics.h>
 #import <QuartzCore/QuartzCore.h>
 
 #include "base/format_macros.h"
 #include "base/i18n/rtl.h"
-#include "base/ios/weak_nsobject.h"
 #include "base/logging.h"
 #include "base/mac/foundation_util.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/strings/grit/components_strings.h"
 #import "ios/chrome/browser/ui/colors/MDCPalette+CrAdditions.h"
 #import "ios/chrome/browser/ui/infobars/infobar_view_delegate.h"
 #include "ios/chrome/browser/ui/ui_util.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #import "ios/chrome/browser/ui/util/label_link_controller.h"
 #import "ios/third_party/material_components_ios/src/components/Buttons/src/MaterialButtons.h"
 #import "ios/third_party/material_components_ios/src/components/Typography/src/MaterialTypography.h"
 #include "ui/base/l10n/l10n_util.h"
 #import "ui/gfx/ios/NSString+CrStringDrawing.h"
 #import "ui/gfx/ios/uikit_util.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 const char kChromeInfobarURL[] = "chromeinternal://infobar/";
 
 // UX configuration constants for the shadow/rounded corners on the icon.
 const CGFloat kBaseSizeForEffects = 57.0;
 const CGFloat kCornerRadius = 10.0;
 const CGFloat kShadowVerticalOffset = 1.0;
 const CGFloat kShadowOpacity = 0.5;
 const CGFloat kShadowRadius = 0.8;
@@ skipping 36 matching lines @@
 // If |layout| is yes, it sets the frame of the label and the switch to fit
 // |width|.
 - (CGFloat)heightRequiredForSwitchWithWidth:(CGFloat)width layout:(BOOL)layout;
 
 // Returns the preferred width. A smaller width requires eliding the text.
 - (CGFloat)preferredWidth;
 
 @end
 
 @implementation SwitchView {
-  base::scoped_nsobject<UILabel> label_;
-  base::scoped_nsobject<UISwitch> switch_;
+  UILabel* label_;
+  UISwitch* switch_;
   CGFloat preferredTotalWidth_;
   CGFloat preferredLabelWidth_;
 }
 
 - (id)initWithLabel:(NSString*)labelText isOn:(BOOL)isOn {
   // Creates switch and label.
-  base::scoped_nsobject<UILabel> tempLabel(
-      [[UILabel alloc] initWithFrame:CGRectZero]);
+  UILabel* tempLabel = [[UILabel alloc] initWithFrame:CGRectZero];
   [tempLabel setTextAlignment:NSTextAlignmentNatural];
   [tempLabel setFont:[MDCTypography body1Font]];
   [tempLabel setText:labelText];
   [tempLabel setBackgroundColor:[UIColor clearColor]];
   [tempLabel setLineBreakMode:NSLineBreakByWordWrapping];
   [tempLabel setNumberOfLines:0];
   [tempLabel setAdjustsFontSizeToFitWidth:NO];
-  base::scoped_nsobject<UISwitch> tempSwitch(
-      [[UISwitch alloc] initWithFrame:CGRectZero]);
+  UISwitch* tempSwitch = [[UISwitch alloc] initWithFrame:CGRectZero];
   [tempSwitch setExclusiveTouch:YES];
   [tempSwitch setAccessibilityLabel:labelText];
   [tempSwitch setOnTintColor:[[MDCPalette cr_bluePalette] tint500]];
   [tempSwitch setOn:isOn];
 
   // Computes the size and initializes the view.
   CGSize maxSize = CGSizeMake(CGFLOAT_MAX, CGFLOAT_MAX);
   CGSize labelSize =
       [[tempLabel text] cr_boundingSizeWithSize:maxSize font:[tempLabel font]];
   CGSize switchSize = [tempSwitch frame].size;
   CGRect frameRect = CGRectMake(
       0, 0, labelSize.width + kSpaceBetweenWidgets + switchSize.width,
       std::max(labelSize.height, switchSize.height));
   self = [super initWithFrame:frameRect];
   if (!self)
     return nil;
-  label_.reset([tempLabel retain]);
-  switch_.reset([tempSwitch retain]);
+  label_ = tempLabel;
+  switch_ = tempSwitch;
 
   // Sets the position of the label and the switch. The label is left aligned
   // and the switch is right aligned. Both are vertically centered.
   CGRect labelFrame =
       CGRectMake(0, (self.frame.size.height - labelSize.height) / 2,
                  labelSize.width, labelSize.height);
   CGRect switchFrame =
       CGRectMake(self.frame.size.width - switchSize.width,
                  (self.frame.size.height - switchSize.height) / 2,
                  switchSize.width, switchSize.height);
@@ skipping 84 matching lines @@
 
 // Returns the marker delimiting the start of a link.
 + (NSString*)openingMarkerForLink;
 // Returns the marker delimiting the end of a link.
 + (NSString*)closingMarkerForLink;
 
 @end
 
 @implementation InfoBarView {
   // Delegates UIView events.
-  InfoBarViewDelegate* delegate_;  // weak
+  InfoBarViewDelegate* delegate_;  // weak.
   // The current height of this infobar (used for animations where part of the
   // infobar is hidden).
   CGFloat visibleHeight_;
   // The height of this infobar when fully visible.
   CGFloat targetHeight_;
   // View containing |imageView_|. Exists to apply drop shadows to the view.
-  base::scoped_nsobject<UIView> imageViewContainer_;
+  UIView* imageViewContainer_;
   // View containing the icon.
-  base::scoped_nsobject<UIImageView> imageView_;
+  UIImageView* imageView_;
   // Close button.
-  base::scoped_nsobject<UIButton> closeButton_;
+  UIButton* closeButton_;
   // View containing the switch and its label.
-  base::scoped_nsobject<SwitchView> switchView_;
+  SwitchView* switchView_;
   // We are using a LabelLinkController with an UILabel to be able to have
   // parts of the label underlined and clickable. This label_ may be nil if
   // the delegate returns an empty string for GetMessageText().
-  base::scoped_nsobject<LabelLinkController> labelLinkController_;
-  UILabel* label_;  // Weak.
+  LabelLinkController* labelLinkController_;
+  UILabel* label_;
   // Array of range information. The first element of the pair is the tag of
   // the action and the second element is the range defining the link.
   std::vector<std::pair<NSUInteger, NSRange>> linkRanges_;
   // Text for the label with link markers included.
-  base::scoped_nsobject<NSString> markedLabel_;
+  NSString* markedLabel_;
   // Buttons.
   // button1_ is tagged with ConfirmInfoBarDelegate::BUTTON_OK .
   // button2_ is tagged with ConfirmInfoBarDelegate::BUTTON_CANCEL .
-  base::scoped_nsobject<UIButton> button1_;
-  base::scoped_nsobject<UIButton> button2_;
+  UIButton* button1_;
+  UIButton* button2_;
   // Drop shadow.
-  base::scoped_nsobject<UIImageView> shadow_;
+  UIImageView* shadow_;
 }
 
 @synthesize visibleHeight = visibleHeight_;
 
 - (instancetype)initWithFrame:(CGRect)frame
                      delegate:(InfoBarViewDelegate*)delegate {
   self = [super initWithFrame:frame];
   if (self) {
     delegate_ = delegate;
     // Make the drop shadow.
     UIImage* shadowImage = [UIImage imageNamed:@"infobar_shadow"];
-    shadow_.reset([[UIImageView alloc] initWithImage:shadowImage]);
+    shadow_ = [[UIImageView alloc] initWithImage:shadowImage];
     [self addSubview:shadow_];
     [self setAutoresizingMask:UIViewAutoresizingFlexibleWidth |
                               UIViewAutoresizingFlexibleHeight];
     [self setAccessibilityViewIsModal:YES];
   }
   return self;
 }
 
-- (void)dealloc {
-  [super dealloc];
-}
 
 - (NSString*)markedLabel {
   return markedLabel_;
 }
 
 - (void)resetDelegate {
   delegate_ = NULL;
 }
 
 // Returns the width reserved for the icon.
@@ skipping 366 matching lines @@
 }
 
 - (void)addCloseButtonWithTag:(NSInteger)tag
                        target:(id)target
                        action:(SEL)action {
   DCHECK(!closeButton_);
   // TODO(crbug/228611): Add IDR_ constant and use GetNativeImageNamed().
   NSString* imagePath =
       [[NSBundle mainBundle] pathForResource:@"infobar_close" ofType:@"png"];
   UIImage* image = [UIImage imageWithContentsOfFile:imagePath];
-  closeButton_.reset([[UIButton buttonWithType:UIButtonTypeCustom] retain]);
+  closeButton_ = [UIButton buttonWithType:UIButtonTypeCustom];
   [closeButton_ setExclusiveTouch:YES];
   [closeButton_ setImage:image forState:UIControlStateNormal];
   [closeButton_ addTarget:target
                    action:action
          forControlEvents:UIControlEventTouchUpInside];
   [closeButton_ setTag:tag];
   [closeButton_ setAccessibilityLabel:l10n_util::GetNSString(IDS_CLOSE)];
   [self addSubview:closeButton_];
 }
 
 - (void)addSwitchWithLabel:(NSString*)label
                       isOn:(BOOL)isOn
                        tag:(NSInteger)tag
                     target:(id)target
                     action:(SEL)action {
-  switchView_.reset([[SwitchView alloc] initWithLabel:label isOn:isOn]);
+  switchView_ = [[SwitchView alloc] initWithLabel:label isOn:isOn];
   [switchView_ setTag:tag target:target action:action];
   [self addSubview:switchView_];
 }
 
 - (void)addLeftIcon:(UIImage*)image {
   if (!imageViewContainer_) {
-    imageViewContainer_.reset([[UIView alloc] init]);
+    imageViewContainer_ = [[UIView alloc] init];
     [self addSubview:imageViewContainer_];
   }
-  imageView_.reset([[UIImageView alloc] initWithImage:image]);
+  imageView_ = [[UIImageView alloc] initWithImage:image];
   [imageViewContainer_ addSubview:imageView_];
 }
 
 - (void)addPlaceholderTransparentIcon:(CGSize const&)imageSize {
   UIGraphicsBeginImageContext(imageSize);
   UIImage* placeholder = UIGraphicsGetImageFromCurrentImageContext();
   UIGraphicsEndImageContext();
   [self addLeftIcon:placeholder];
 }
 
@@ skipping 16 matching lines @@
 }
 
 - (NSString*)stripMarkersFromString:(NSString*)string {
   linkRanges_.clear();
   for (;;) {
     // Find the opening marker, followed by the tag between parentheses.
     NSRange startingRange =
         [string rangeOfString:[[InfoBarView openingMarkerForLink]
                                   stringByAppendingString:@"("]];
     if (!startingRange.length)
-      return [[string copy] autorelease];
+      return [string copy];
     // Read the tag.
     NSUInteger beginTag = NSMaxRange(startingRange);
     NSRange closingParenthesis = [string
         rangeOfString:@")"
               options:NSLiteralSearch
                 range:NSMakeRange(beginTag, [string length] - beginTag)];
     if (closingParenthesis.location == NSNotFound)
-      return [[string copy] autorelease];
+      return [string copy];
     NSInteger tag = [[string
         substringWithRange:NSMakeRange(beginTag, closingParenthesis.location -
                                                      beginTag)] integerValue];
     // If the parsing fails, |tag| is 0. Negative values are not allowed.
     if (tag <= 0)
-      return [[string copy] autorelease];
+      return [string copy];
     // Find the closing marker.
     startingRange.length =
         closingParenthesis.location - startingRange.location + 1;
     NSRange endingRange =
         [string rangeOfString:[InfoBarView closingMarkerForLink]];
     DCHECK(endingRange.length);
     // Compute range of link in stripped string and add it to the array.
     NSRange rangeOfLinkInStrippedString =
         NSMakeRange(startingRange.location,
                     endingRange.location - NSMaxRange(startingRange));
     linkRanges_.push_back(std::make_pair(tag, rangeOfLinkInStrippedString));
     // Creates a new string without the markers.
     NSString* beforeLink = [string substringToIndex:startingRange.location];
     NSRange rangeOfLink =
         NSMakeRange(NSMaxRange(startingRange),
                     endingRange.location - NSMaxRange(startingRange));
     NSString* link = [string substringWithRange:rangeOfLink];
     NSString* afterLink = [string substringFromIndex:NSMaxRange(endingRange)];
     string = [NSString stringWithFormat:@"%@%@%@", beforeLink, link, afterLink];
   }
 }
 
 - (void)addLabel:(NSString*)label {
   [self addLabel:label action:nil];
 }
 
 - (void)addLabel:(NSString*)text action:(void (^)(NSUInteger))action {
-  markedLabel_.reset([text copy]);
+  markedLabel_ = [text copy];
   if (action)
     text = [self stripMarkersFromString:text];
   if ([label_ superview]) {
     [label_ removeFromSuperview];
   }
 
-  label_ = [[[UILabel alloc] initWithFrame:CGRectZero] autorelease];
+  label_ = [[UILabel alloc] initWithFrame:CGRectZero];
 
   UIFont* font = [MDCTypography subheadFont];
 
   [label_ setBackgroundColor:[UIColor clearColor]];
 
   NSMutableParagraphStyle* paragraphStyle =
-      [[[NSMutableParagraphStyle alloc] init] autorelease];
+      [[NSMutableParagraphStyle alloc] init];
   paragraphStyle.lineBreakMode = NSLineBreakByWordWrapping;
   paragraphStyle.lineSpacing = kLabelLineSpacing;
   NSDictionary* attributes = @{
     NSParagraphStyleAttributeName : paragraphStyle,
     NSFontAttributeName : font,
   };
   [label_ setNumberOfLines:0];
 
-  [label_ setAttributedText:[[[NSAttributedString alloc]
-                                initWithString:text
-                                    attributes:attributes] autorelease]];
+  [label_
+      setAttributedText:[[NSAttributedString alloc] initWithString:text
+                                                        attributes:attributes]];
 
   [self addSubview:label_];
 
   if (linkRanges_.empty())
     return;
 
-  labelLinkController_.reset([[LabelLinkController alloc]
+  labelLinkController_ = [[LabelLinkController alloc]
       initWithLabel:label_
              action:^(const GURL& gurl) {
                if (action) {
                  NSUInteger actionTag = [base::SysUTF8ToNSString(
                      gurl.ExtractFileName()) integerValue];
                  action(actionTag);
                }
-             }]);
+             }];
 
   [labelLinkController_ setLinkUnderlineStyle:NSUnderlineStyleSingle];
   [labelLinkController_ setLinkColor:[UIColor blackColor]];
 
   std::vector<std::pair<NSUInteger, NSRange>>::const_iterator it;
   for (it = linkRanges_.begin(); it != linkRanges_.end(); ++it) {
     // The last part of the URL contains the tag, so it can be retrieved in the
     // callback. This tag is generally a command ID.
     std::string url = std::string(kChromeInfobarURL) +
                       std::string(std::to_string((int)it->first));
     [labelLinkController_ addLinkWithRange:it->second url:GURL(url)];
   }
 }
 
 - (void)addButton1:(NSString*)title1
               tag1:(NSInteger)tag1
            button2:(NSString*)title2
               tag2:(NSInteger)tag2
             target:(id)target
             action:(SEL)action {
-  button1_.reset([[self infoBarButton:title1
-                              palette:[MDCPalette cr_bluePalette]
-                     customTitleColor:[UIColor whiteColor]
-                                  tag:tag1
-                               target:target
-                               action:action] retain]);
+  button1_ = [self infoBarButton:title1
+                         palette:[MDCPalette cr_bluePalette]
+                customTitleColor:[UIColor whiteColor]
+                             tag:tag1
+                          target:target
+                          action:action];
   [self addSubview:button1_];
 
-  button2_.reset([[self infoBarButton:title2
-                              palette:nil
-                     customTitleColor:UIColorFromRGB(kButton2TitleColor)
-                                  tag:tag2
-                               target:target
-                               action:action] retain]);
+  button2_ = [self infoBarButton:title2
+                         palette:nil
+                customTitleColor:UIColorFromRGB(kButton2TitleColor)
+                             tag:tag2
+                          target:target
+                          action:action];
   [self addSubview:button2_];
 }
 
 - (void)addButton:(NSString*)title
               tag:(NSInteger)tag
            target:(id)target
            action:(SEL)action {
   if (![title length])
     return;
-  button1_.reset([[self infoBarButton:title
-                              palette:[MDCPalette cr_bluePalette]
-                     customTitleColor:[UIColor whiteColor]
-                                  tag:tag
-                               target:target
-                               action:action] retain]);
+  button1_ = [self infoBarButton:title
+                         palette:[MDCPalette cr_bluePalette]
+                customTitleColor:[UIColor whiteColor]
+                             tag:tag
+                          target:target
+                          action:action];
   [self addSubview:button1_];
 }
 
 // Initializes and returns a button for the infobar, with the specified
 // |message| and colors.
 - (UIButton*)infoBarButton:(NSString*)message
                    palette:(MDCPalette*)palette
           customTitleColor:(UIColor*)customTitleColor
                        tag:(NSInteger)tag
                     target:(id)target
                     action:(SEL)action {
-  base::scoped_nsobject<MDCFlatButton> button([[MDCFlatButton alloc] init]);
-  button.get().inkColor = [[palette tint300] colorWithAlphaComponent:0.5f];
+  MDCFlatButton* button = [[MDCFlatButton alloc] init];
+  button.inkColor = [[palette tint300] colorWithAlphaComponent:0.5f];
   [button setBackgroundColor:[palette tint500] forState:UIControlStateNormal];
   [button setBackgroundColor:[UIColor colorWithWhite:0.8f alpha:1.0f]
                     forState:UIControlStateDisabled];
   if (palette)
-    button.get().hasOpaqueBackground = YES;
+    button.hasOpaqueBackground = YES;
   if (customTitleColor) {
-    button.get().tintAdjustmentMode = UIViewTintAdjustmentModeNormal;
-    button.get().customTitleColor = customTitleColor;
+    button.tintAdjustmentMode = UIViewTintAdjustmentModeNormal;
+    button.customTitleColor = customTitleColor;
   }
-  button.get().titleLabel.adjustsFontSizeToFitWidth = YES;
-  button.get().titleLabel.minimumScaleFactor = 0.6f;
+  button.titleLabel.adjustsFontSizeToFitWidth = YES;
+  button.titleLabel.minimumScaleFactor = 0.6f;
   [button setTitle:message forState:UIControlStateNormal];
   [button setTag:tag];
   [button addTarget:target
                 action:action
       forControlEvents:UIControlEventTouchUpInside];
   // Without the call to layoutIfNeeded, |button| returns an incorrect
   // titleLabel the first time it is accessed in |narrowestWidthOfButton|.
   [button layoutIfNeeded];
-  return button.autorelease();
+  return button;
 }
 
 - (CGRect)frameOfCloseButton:(BOOL)singleLineMode {
   DCHECK(closeButton_);
   // Add padding to increase the touchable area.
   CGSize closeButtonSize = [closeButton_ imageView].image.size;
   closeButtonSize.width += kCloseButtonInnerPadding * 2;
   closeButtonSize.height += kCloseButtonInnerPadding * 2;
   CGFloat x = CGRectGetMaxX(self.frame) - closeButtonSize.width;
   // Aligns the close button at the top (height includes touch padding).
@@ skipping 41 matching lines @@
 
 - (CGFloat)buttonMargin {
   return kButtonMargin;
 }
 
 - (const std::vector<std::pair<NSUInteger, NSRange>>&)linkRanges {
   return linkRanges_;
 }
 
 @end